Scacchiera Zoomante

[iAN CooG]

Effetto simpatico trovato in un mini intro di Crossbow/Crest. Una scacchiera zoomante in modo testo e in meno di 128 bytes

Codice: [Seleziona]

; 128 byte checkerboard zoomer
; ripped from "2 BLOCKS TRACKMO" by Xbow/Crest
; isolated, disasmed and reduced by iAN CooG/HokutoForce

                *=$0801

                word eop
                word 0
                byte $9e,[start]d," (C) XBOW/CREST"
eop             byte 0
start
loop1           LDX #$00
patch           INX
                CPX #$F8
                BEQ next1

                CPX #$28
                BNE nopat

next1           LDA patch
                EOR #$22 ; INX=$E8 DEX=$CA
                STA patch
nopat           STX loop1+1
                LDA #$20
                STA $3F
                LDA #$04
                STA $3C
                STX $3D
                STX $3E
                LDA #$00
next2           STA $3B
                LDY #$27
                LDA $3F
loop2           STA ($3B),Y
                DEX
                BPL noeor

                LDX $3E
                EOR #$80 ; reverse/normal space
noeor           DEY
                BPL loop2

                LDX $3E
                DEC $3D
                BPL noeor2

                LDA $3F
                EOR #$80 ; reverse/normal space
                STA $3F
                STX $3D
noeor2          LDA $3B
                CLC
                ADC #$28
                BCC noinchi

                INC $3C
noinchi         CMP #$E8
                BNE next2

                LDA #$FF
w8rast
                CMP $D012
                BNE w8rast

                BEQ loop1