10755 clr
10756 poke53272,23
10764 print"{CLEAR}"
10767 op=0
10769 dimog(160)
10777 dimog$(160)
10785 dimge$(160)
10793 dimar$(160)
10801 dimde$(160)
10809 dimaz$(50)
10817 dimj(36)
10825 print"{CLEAR}{GREEN}"
10829 poke53280,6
10837 poke53281,6
10845 print
10846 print
10847 print"{WHITE}SPRITES ADVENTURE  by Marcello Giombini"
10890 print
10891 print
10892 printtab(24);
10894 print"{REVERSE ON}Attendere,prego"
10913 te$="000000"
10921 z4$="fiaschetta"
10934 gn$="{CLEAR}l'ago segna "
10950 z1$="specchio"
10961 z2$="coltello"
10972 z3$="focaccia"
10983 ix$="{CLEAR}istruzione incompleta!"
11009 hp$="{CLEAR}hai preso "
11023 nh$="{CLEAR}tu non hai "
11038 ve$="{REVERSE ON}vedi{REVERSE OFF}:"
11047 hl$="{CLEAR}hai lasciato "
11064 pt$="{CLEAR}perche' perdi tempo prezioso?"
11097 pa$=" "
11100 dv$="{CLEAR}non puoi!"
11113 kj$="{REVERSE ON}                                       "
11156 gosub26383
11159 az=1
11160 foraz=1to41
11166 readaz$(az)
11170 next
11171 g=7
11172 forg=7to152
11178 readog(g)
11182 readog$(g)
11186 readar$(g)
11190 readge$(g)
11194 readde$(g)
11198 next
11199 print"{CLEAR}"
11202 poke53280,5
11210 poke53281,5
11218 print"{BLUE}Hai dati da caricare(s/n)?"
11248 getd$
11250 ifd$=""goto11248
11256 ifd$<>"s"andd$<>"n"goto11218
11268 ifd$="s"goto15814
11275 poke53265,11
11283 zz=1
11284 forzz=1to36
11290 j(zz)=0
11294 next
11295 l=19
11297 nk=0
11299 aa=0
11301 ab=0
11303 ac=0
11305 ad=0
11307 ae=0
11309 af=0
11311 ag=0
11313 ah=0
11315 ai=0
11317 al=0
11319 pa=0
11322 pc=0
11325 ti$=te$
11327 print"{CLEAR}"
11330 print
11331 gosub15609
11334 ifval(ti$)>50000goto15701
11346 ifl<11thenonlgosub12764,12838,12904,13004,13077,13146,13217,13286,13359,13432:goto11472
11377 ifl<21thenonl-10gosub13495,13576,13644,13713,13811,13905,14017,14088,14153,14248
11407 ifl<21goto11472
11413 ifl<31thenonl-20gosub14327,14386,14450,14511,14590,14659,14721,14813,14893,14963
11443 ifl<31goto11472
11449 ifl<41thenonl-30gosub15040,15117,15178,15255,15342,15519
11472 g=80
11474 forg=80to152
11480 ifog(g)=lthenprintge$(g);:printog$(g);:print" ";:printde$(g)
11502 next
11503 poke19,65
11507 poke53265,27
11515 print"{REVERSE ON}cosa fai?{REVERSE OFF} ";
11530 poke53265,27
11538 inputi$
11542 ln=len(i$)
11547 poke53265,11
11555 n$=""
11558 z=1
11560 forz=1toln
11566 ifmid$(i$,z,1)=" "theni=z:goto11588
11584 next
11585 i=0
11588 ifi=0thenv$=i$:goto11654
11601 z=ln
11604 forz=lnto1step-1
11611 ifmid$(i$,z,1)=" "ormid$(i$,z,1)="'"goto11634
11633 next
11634 v$=left$(i$,i-1)
11643 n$=mid$(i$,z+1)
11654 i=0
11657 az=1
11658 foraz=1to50
11664 ifaz$(az)=v$goto11706
11673 next
11674 print"{CLEAR}non conosco la parola ";
11700 printv$
11703 goto11330
11706 g=7
11707 forg=7to152
11713 ifn$=left$(og$(g),len(n$))goto11749
11726 next
11727 print
11728 print"{CLEAR}cos'hai detto?"
11746 goto11330
11749 ifae=1andaf=0thenl=19:printbg$:printbh$:printbi$:printbl$:af=1:goto11330
11777 print
11778 print
11779 ifi$="n"ori$="e"ori$="s"ori$="o"goto12443
11805 ifi$="p"goto31546
11813 ifi$="v"goto12274
11821 ifi$="i"goto12681
11829 ifi$="f"thenpoke53265,27:print"{CLEAR}":poke19,0:end
11851 ifv$="r"thenpoke53265,27:te$=ti$:goto15990
11871 ifv$="t"goto12304
11879 ifv$="d"goto22414
11887 ifn$=""orlen(n$)<4thenprintix$:goto11330
11904 ifv$="prendo"goto16158
11917 ifv$="lascio"orv$="offro"goto16524
11940 ifv$="esamino"orv$="leggo"goto19158
11964 ifv$="seguo"goto20803
11976 ifv$="origlio"goto20892
11990 ifv$="scendo"goto16960
12003 ifv$="salgo"orv$="monto"goto17320
12025 ifv$="saluto"orv$="parlo"goto17635
12048 ifv$="apro"goto18585
12059 ifv$="immergo"goto18480
12073 ifv$="mangio"goto20959
12086 ifv$="bevo"goto21056
12097 ifv$="frugo"goto21453
12109 ifv$="cerco"goto21582
12121 ifv$="grido"goto21761
12133 ifv$="uso"orv$="suono"goto17084
12153 ifv$="busso"goto21937
12165 ifv$="entro"goto18000
12177 ifv$="esco"goto18886
12188 ifv$="mostro"goto22019
12201 ifv$="affronto"goto21213
12217 ifv$="sposto"goto20892
12230 ifv$="rovescio"goto22349
12246 ifv$="infilo"goto21520
12259 ifv$="scavo"goto21026
12271 goto11327
12274 print"{CLEAR}{REVERSE ON}verbi{REVERSE OFF}:";
12286 az=12
12287 foraz=12to40
12293 printaz$(az);
12297 printpa$;
12299 next
12300 print
12301 goto11330
12304 print"{CLEAR}penalita':";
12318 printnk;
12320 print"      tempo attuale ore:";
12347 printleft$(ti$,2)
12351 print"                                 min:";
12391 printmid$(ti$,3,2)
12396 print"                                 sec:";
12436 printright$(ti$,2)
12440 goto11330
12443 ifl=19andj(19)=0thenag=1:printeg$:goto11330
12462 ifi$="n"andag=1ori$="e"andag=1ori$="s"andag=1goto11330
12494 ifl=27andj(27)=0andi$="s"thenprintfm$:goto11330
12517 ifl=8andj(8)=0andi$="n"thenprintfp$:goto11330
12540 ifi$="n"andl=11andog(80)=11thenprintaj$:goto11330
12564 ifl=20andi$="n"thenl=l-12:goto11327
12582 ifl=8andi$="s"thenl=l+12:goto11327
12600 ifi$="n"andn>0thenl=l-6:goto11327
12619 ifi$="e"ande>0thenl=l+1:goto11327
12638 ifi$="s"ands>0thenl=l+6:goto11327
12657 ifi$="o"ando>0thenl=l-1:goto11327
12676 printdv$
12678 goto11330
12681 print"{CLEAR}{REVERSE ON}hai con te{REVERSE OFF}:";
12698 in=0
12701 g=120
12703 forg=120to152
12709 ifog(g)=-1thenprinttab(12);:printar$(g);:printog$(g):in=in+1
12733 next
12734 ifin=0thenprint"{HOME}{RIGHT}{RIGHT}{RIGHT}{RIGHT}{RIGHT}{RIGHT}{RIGHT}{RIGHT}{RIGHT}{RIGHT}{RIGHT}{RIGHT}nulla"
12761 goto11330
12764 printkj$
12766 print"Sei sul terrazzino del faro...."
12800 printve$
12802 print"una scala che scende"
12825 n=0
12828 e=0
12831 s=0
12834 o=0
12837 return
12838 printkj$
12840 print"Sei in una piccola stalla...."
12872 printve$
12874 print"una mangiatoia"
12891 n=0
12894 s=1
12897 e=0
12900 o=0
12903 return
12904 printkj$
12906 print"Sei sul terrazzo della torre...."
12941 printve$
12943 print"i merli che lo cingono"
12968 print"una scala che scende"
12991 n=0
12994 s=0
12997 e=0
13000 o=0
13003 return
13004 printkj$
13006 print"Sei in un locale della torre...."
13041 printve$
13043 print"una scala che sale"
13064 n=0
13067 s=1
13070 e=0
13073 o=0
13076 return
13077 printkj$
13079 print"Sei in un prato...."
13101 printve$
13103 print"un salice"
13115 print"degli alberelli"
13133 n=0
13136 s=1
13139 e=0
13142 o=0
13145 return
13146 printkj$
13148 j(6)=j(6)+1
13156 print"Sei in una caverna...."
13181 printve$
13183 print"un grosso forziere"
13204 n=0
13207 s=1
13210 e=0
13213 o=0
13216 return
13217 printkj$
13219 print"Sei all'interno del faro...."
13250 printve$
13252 print"una scala che sale"
13273 n=0
13276 s=1
13279 e=0
13282 o=0
13285 return
13286 printkj$
13288 ifj(8)=1thenn1=1
13298 print"Sei su un incolto terreno...."
13330 printve$
13332 print"una stalla"
13345 n=n1
13349 s=1
13352 e=0
13355 o=0
13358 return
13359 printkj$
13361 print"Sei all'interno del mulino...."
13394 printve$
13396 print"una pietra da macina"
13419 n=1
13422 s=1
13425 e=0
13428 o=0
13431 return
13432 printkj$
13434 print"Sei all'interno della rocca...."
13468 printve$
13470 print"una torre"
13482 n=1
13485 s=1
13488 e=0
13491 o=0
13494 return
13495 printkj$
13497 print"Sei su un sentiero fra le rocce...."
13535 printve$
13537 print"piccole fluttuanti luci"
13563 n=1
13566 s=0
13569 e=1
13572 o=0
13575 return
13576 printkj$
13578 print"Sei in una radura...."
13602 printve$
13604 print"l'entrata di una caverna"
13631 n=0
13634 s=1
13637 e=0
13640 o=1
13643 return
13644 printkj$
13646 print"Sei su una bianca scogliera...."
13680 printve$
13682 print"un vecchio faro"
13700 n=1
13703 s=1
13706 e=0
13709 o=0
13712 return
13713 printkj$
13715 print"Sei all'interno della quercia...."
13751 printve$
13753 print"strane luci fluttuanti"
13778 print"una botola chiusa"
13798 n=0
13801 s=0
13804 e=0
13807 o=0
13810 return
13811 printkj$
13813 print"Sei su un viottolo...."
13838 ifj(15)=1goto13872
13846 print"si ode un lieve battito"
13872 printve$
13874 print"una fitta siepe"
13892 n=1
13895 s=1
13898 e=0
13901 o=0
13904 return
13905 printkj$
13907 print"Sei sulla knowe...."
13929 printve$
13931 print"un'antica rocca"
13949 ifpa=1goto13980
13956 ifpc=1thenprint"una door chiusa"
13980 ifpa=1thenprint"una door aperta"
14004 n=1
14007 s=0
14010 e=0
14013 o=0
14016 return
14017 printkj$
14019 print"Sei all'interno della capanna...."
14055 printve$
14057 print"un pagliericcio"
14075 n=0
14078 s=0
14081 e=0
14084 o=0
14087 return
14088 printkj$
14090 print"Sei in un vecchio cimitero...."
14123 printve$
14125 print"dei cipressi"
14140 n=1
14143 s=1
14146 e=0
14149 o=0
14152 return
14153 printkj$
14155 print"Sei su una spiaggia...."
14181 ifog(120)=0thenprint"odi uno strano lamento"
14214 printve$
14216 print"una piccola duna"
14235 n=1
14238 s=1
14241 e=1
14244 o=0
14247 return
14248 printkj$
14250 print"Sei in un orto pieno di erbacce...."
14288 printve$
14290 print"una capanna"
14304 ifj(20)=1thenprintal$
14314 n=1
14317 s=0
14320 e=1
14323 o=1
14326 return
14327 printkj$
14329 print"Sei in un fitto bosco...."
14357 printve$
14359 print"una quercia"
14373 n=1
14376 s=1
14379 e=1
14382 o=1
14385 return
14386 printkj$
14388 print"Sei al disotto di una knowe"
14418 printve$
14420 print"molti cespugli"
14437 n=0
14440 s=1
14443 e=1
14446 o=1
14449 return
14450 printkj$
14452 print"Sei su un viottolo...."
14477 printve$
14479 print"un vasto canneto"
14498 n=0
14501 s=0
14504 e=1
14507 o=1
14510 return
14511 printkj$
14513 print"Sei dentro una chiesa sconsacrata...."
14553 printve$
14555 print"l'altare fra i rovi"
14577 n=1
14580 s=1
14583 e=0
14586 o=1
14589 return
14590 printkj$
14592 print"Sei sulla brughiera...."
14618 printve$
14620 print"l'entrata di una grotta"
14646 n=1
14649 s=0
14652 e=0
14655 o=0
14658 return
14659 printkj$
14661 print"Sei nel granaio...."
14683 printve$
14685 print"una scala che scende"
14708 n=0
14711 s=0
14714 e=0
14717 o=0
14720 return
14721 printkj$
14723 ifj(27)=1thens1=1
14733 print"Sei davanti a una fattoria...."
14766 printve$
14768 print"una scala che sale al granaio"
14800 n=1
14803 s1=0
14806 e=1
14809 o=0
14812 return
14813 printkj$
14815 print"Sei davanti a un fontanile...."
14848 printve$
14850 print"la luna riflessa nell'acqua"
14880 n=0
14883 s=0
14886 e=0
14889 o=1
14892 return
14893 printkj$
14895 print"Sei in fondo a un pozzo...."
14925 printve$
14927 print"l'orifizio del pozzo"
14950 n=0
14953 s=0
14956 e=0
14959 o=0
14962 return
14963 printkj$
14965 print"Sei su uno spiazzo terroso...."
14998 printve$
15000 print"l'entrata di una miniera"
15027 n=1
15030 s=0
15033 e=0
15036 o=0
15039 return
15040 printkj$
15042 print"Sei in una grotta altissima...."
15076 printve$
15078 print"un grosso cubo roccioso"
15104 n=1
15107 s=0
15110 e=0
15113 o=0
15116 return
15117 printkj$
15119 print"Sei in un'annerita cucina...."
15151 printve$
15153 print"un camino"
15165 n=0
15168 s=0
15171 e=1
15174 o=0
15177 return
15178 printkj$
15180 print"Sei all'interno della fattoria...."
15217 printve$
15219 print"una scala che scende"
15242 n=1
15245 s=0
15248 e=0
15251 o=1
15254 return
15255 printkj$
15257 print"Sei in un'umida cantina...."
15287 printve$
15289 print"una scala che sale"
15310 print"una grossa botte"
15329 n=0
15332 s=0
15335 e=0
15338 o=0
15341 return
15342 printkj$
15344 ad=ad+1
15348 print"Sei in un buio mare agitato...."
15382 print"ma non sai nuotare!...."
15408 print"stai annegando!...."
15430 ifad=2thenog(90)=l
15440 ifad=3thenog(91)=l
15450 ifad=4thenog(92)=l
15460 ifad=5thenog(93)=l
15470 ifad=6thenog(94)=l
15480 ifad=7thenog(95)=l
15490 ifad=8thenog(96)=l:ae=1:nk=nk+1
15506 n=0
15509 e=0
15512 s=0
15515 o=0
15518 return
15519 printkj$
15521 print"Sei in una vecchia  miniera...."
15555 printve$
15557 print"una galleria franata"
15580 print"un carrello"
15594 n=1
15597 e=0
15600 s=0=o=0
15608 return
15609 ifnk=0thenreturn
15613 onnkgoto15632,15640,15648,15656,15664,15672,15680,15688
15632 tk$="01"
15637 goto15693
15640 tk$="02"
15645 goto15693
15648 tk$="03"
15653 goto15693
15656 tk$="04"
15661 goto15693
15664 tk$="05"
15669 goto15693
15672 tk$="06"
15677 goto15693
15680 tk$="07"
15685 goto15693
15688 tk$="08"
15693 ti$=tk$+right$(ti$,4)
15700 return
15701 print"{CLEAR}Il tempo e' scaduto!L'avventura e' finita!"
15747 print"Vuoi giocare ancora(s/n)?"
15775 getk$
15778 ifk$=""goto15775
15785 ifk$<>"s"andk$<>"n"goto15701
15799 ifk$="s"goto10756
15807 print"{CLEAR}"
15810 poke19,0
15813 end
15814 print"{CLEAR}Inserisci cassetta dati e premi {REVERSE ON}RETURN"
15857 getd$
15859 ifd$=""goto15857
15865 ifd$<>chr$(13)goto15814
15872 open1,1,0,"fo"
15880 g=80
15882 forg=80to152
15888 input#1,og(g)
15894 next
15895 tk=1
15897 fortk=1to36
15903 input#1,j(tk)
15910 next
15911 input#1,l
15916 input#1,te$
15920 input#1,nk
15925 input#1,aa
15930 input#1,ab
15935 input#1,ac
15940 input#1,ad
15945 input#1,ae
15950 input#1,af
15955 input#1,ag
15960 input#1,ah
15965 input#1,ai
15970 input#1,al
15975 input#1,pa
15980 input#1,pc
15985 close1
15987 goto11325
15990 print"{CLEAR}Inserisci cassetta dati e premi {REVERSE ON}RETURN"
16033 getd$
16035 ifd$=""goto16033
16041 ifd$<>chr$(13)goto15990
16048 open1,1,1,"fo"
16056 g=80
16058 forg=80to152
16064 print#1,og(g)
16070 next
16071 tk=1
16073 fortk=1to36
16079 print#1,j(tk)
16086 next
16087 print#1,l
16091 print#1,te$
16095 print#1,nk
16099 print#1,aa
16103 print#1,ab
16107 print#1,ac
16111 print#1,ad
16115 print#1,ae
16119 print#1,af
16123 print#1,ag
16127 print#1,ah
16131 print#1,ai
16135 print#1,al
16139 print#1,pa
16144 print#1,pc
16149 close1
16151 print"{CLEAR}"
16154 poke19,0
16157 end
16158 ifn$="pietra"andl=13thenprintao$:goto11330
16180 ifn$="cosa"andl=5thenprintfe$:og(139)=-1:op=op+1:goto11330
16210 ifn$="piccione"thenprintff$:goto11330
16231 ifn$="knocker"thenprintff$:goto11330
16250 ifn$="funghi"andl=14orn$="nani"andl=14thenprinteg$:goto11330
16285 ifg<120thenprintdv$:goto11330
16296 ifog(g)=-1thenprint"{CLEAR}hai gia' ";:printar$(g);:printn$:goto11330
16327 ifop>4thenprint"{CLEAR}no! hai gia' 5 oggetti":goto11330
16361 ifog(g)<>lthenprint"{CLEAR}io non vedo ";:printar$(g);:printog$(g):goto11330
16395 ifn$="leprecaun"andl=15goto25862
16416 ifn$="fungo"thenog(110)=0:j(21)=1
16436 ifn$="tesoro"andl=29thenj(29)=2
16456 ifn$="cosa"andl=5thenprintfe$:og(139)=-1:op=op+1:goto11330
16486 ifn$=og$(g)thenog(g)=-1:op=op+1
16503 ifn$=og$(g)thenprinthp$;:printar$(g);:printog$(g):goto11330
16524 ifog(g)<>-1thenprintnh$;:printar$(g);:printog$(g):goto11330
16545 ifn$="leprecaun"thenog(121)=0:op=op-1:j(15)=1:goto31058
16577 ifn$="pasticcio"andl=7andog(98)=lthenprintbp$:j(7)=1
16611 ifn$="pasticcio"andl=7andog(98)=lthenog(98)=0:og(127)=0:op=op-1:goto11330
16655 ifn$="pane"andl=30andog(109)=30thenprintco$
16679 ifn$="pane"andl=30andog(109)=30thenog(109)=0:og(131)=0:op=op-1:goto11330
16717 ifn$="sacchetto"andl=9andog(103)=lthenprintdg$:printdh$:j(9)=1
16754 ifn$="sacchetto"andl=9andog(103)=lthenog(144)=l:og(138)=0:op=op-1:goto11330
16798 ifn$=z4$andl=34andog(102)=lthenprintdd$:printdf$:og(151)=l
16827 ifn$=z4$andl=34andog(102)=lthenog(129)=0:op=op-1:goto11330
16857 ifn$=z3$andl=17andog(139)=-1andog(111)=lthenprintdo$:printdp$
16888 ifn$=z3$andl=17andog(139)=-1andog(111)=lthenog(139)=0:ad=1:goto11330
16923 ifog(g)=-1thenprinthl$;:printar$(g);:printog$(g)
16941 ifog(g)=-1thenog(g)=l:op=op-1:goto11330
16960 ifn$="knowe"andl=16orn$="collina"andl=16thenl=22:goto11327
16996 ifn$="scala"andl=1thenl=7:goto11327
17016 ifn$="scala"andl=26thenl=27:goto11327
17036 ifn$="scala"andl=33thenl=34:goto11327
17058 ifv$="scendo"thenprint"{CLEAR}scendi?":goto11330
17084 ifog(g)<>-1thenprintnh$;:printar$(g);:printog$(g):goto11330
17105 ifn$="ryegrass"thenprint"{CLEAR}cosa gridi?":goto11330
17138 ifn$="campanella"andl=8andog(115)=lthenprintfq$:og(115)=0:j(8)=1:goto11330
17181 ifn$="chiave"andl=6andai=1thenprintej$:goto11330
17207 ifog(g)<>-1thenprintnh$;:printar$(g);:printog$(g):goto11330
17228 ifv$="suono"thenprint"{CLEAR}questo suono effetto non fa'!":goto11330
17275 ifv$="uso"thenprint"{CLEAR}quel che usi effetto non fa'!":goto11330
17320 ifn$="knowe"andl=22andab=1thenl=16:goto11327
17344 ifn$="knowe"andl=22andab=0thenprintbm$:goto11330
17369 ifn$="scala"andl=27andj(27)=1thenl=26:goto11327
17395 ifn$="scala"andl=34thenl=33:goto11327
17417 ifn$="scala"andl=4andog(82)=0thenl=3:goto11327
17444 ifn$="scala"andl=4andog(82)=lthenprintar$:goto11330
17472 ifn$="scala"andl=27andj(27)=0thenprintfm$:goto11330
17499 ifn$="cavallo"andog(89)=2thenprintbe$:printbf$:og(89)=0:l=35:goto11330
17536 ifn$="scala"andl=7andj(7)=1thenl=1:goto11327
17562 ifn$="scala"andl=7andj(7)=0thenprintas$:goto11330
17589 ifv$="salgo"thenprint"{CLEAR}lascia perdere,non e'per te!":goto11330
17635 ifn$="cluricaun"andl=34thenprintcz$:goto11330
17662 ifn$="killmoulis"andl=9thenprintbb$:goto11330
17689 ifn$="leprecaun"andl=15thenprintag$:printah$:goto11330
17718 ifn$="redcap"andl=4thenprintax$:goto11330
17740 ifn$="goblin"andog(98)=landl=7thenprintal$:printam$:og(124)=l:goto11330
17777 ifn$="oakman"andl=21thenprintcp$:printcq$:og(132)=l:goto11330
17807 ifn$="brownie"andl=17thenprintdn$:goto11330
17830 ifn$="ogre"andl=6thenprint"{CLEAR}ti risponde:grrrrrrrr!!":goto11330
17874 ifn$="knocker"andl=36thenprintfh$:goto11330
17898 ifn$="nano"andl=14thenprintfj$:goto11330
17918 ifv$="saluto"thenprint"{CLEAR}il tuo saluto risposta non ha!":goto11330
17967 ifv$="parlo"thenprint"{CLEAR}fiato sprecato!":goto11330
18000 ifn$="faro"andl=13thenl=7:goto11327
18019 ifn$="torre"andl=10thenl=4:goto11327
18039 ifn$="caverna"andl=12andog(105)=0thenl=6:goto11327
18068 ifn$="caverna"andl=12andog(105)=lthenprintce$:goto11330
18098 ifn$="mulino"andl=15thenl=9:goto11327
18119 ifn$="grotta"andl=25andj(25)=1thenl=31:goto11327
18146 ifn$="grotta"andl=25andj(25)=0thenprintcl$:og(107)=l:goto11330
18179 ifn$="rocca"andl=16thenl=10:goto11327
18199 ifn$="fattoria"andl=27andj(27)=1thenl=33:goto11327
18230 ifn$="miniera"andl=30andog(109)=0thenl=36:goto11327
18260 ifn$="miniera"andl=30andog(109)=lthenprintcn$:goto11330
18290 ifn$="stalla"andl=8andj(8)=1thenl=2:goto11327
18317 ifn$="fattoria"andl=27andj(27)=0thenprintfm$:goto11330
18348 ifn$="apertura"andl=21thenl=14:goto11327
18372 ifn$="capanna"andl=20thenl=17:goto11327
18394 ifn$="door"andl=16andpa=1goto25965
18414 ifn$="stalla"andl=8andj(8)=0thenprintfp$:goto11330
18442 ifv$="entro"thenprint"{CLEAR}non e' cosi' facile!":goto11330
18480 ifn$="sirena"andl=19andog(120)=-1thenog(120)=80:op=op-1:goto30925
18517 ifn$="sirena"andl=19andog(120)<>-1thenprintac$:goto11330
18547 ifv$="immergo"thenprint"{CLEAR}se ti fa' piacere!":goto11330
18585 ifn$="sacchetto"thenprintcv$:printda$:og(138)=80:nk=nk+1:goto11330
18620 ifn$="fiaschetta"thenprintcx$:printck$:og(129)=80:nk=nk+1:goto11330
18656 ifn$="libro"andog(141)=0thenprinten$:og(141)=l:goto11330
18685 ifn$="cofanetto"andl=29thenprintej$:j(29)=1:goto11330
18715 ifn$="porta"thenprint"{CLEAR}come fai?":goto11330
18742 ifn$="forziere"andl=6andai=1thenprintft$:goto11330
18771 ifn$="forziere"andl=6andog(86)=0thenprintek$:printex$:og(86)=l:goto11330
18811 ifn$="forziere"andl=6andog(86)=lthenprintfa$:goto11330
18843 ifv$="apro"thenprint"{CLEAR}non mi sembra cosi' facile":goto11330
18886 ifn$="faro"andl=7thenl=13:goto11327
18905 ifn$="torre"andl=4thenl=10:goto11327
18925 ifn$="caverna"andl=6thenl=12:goto11327
18947 ifn$="mulino"andl=9thenl=15:goto11327
18968 ifn$="grotta"andl=31thenl=25:goto11327
18989 ifn$="rocca"andl=10thenl=16:goto11327
19009 ifn$="fattoria"andl=33thenl=27:goto11327
19034 ifn$="miniera"andl=36thenl=30:goto11327
19057 ifn$="stalla"andl=2thenl=8:goto11327
19078 ifn$="quercia"andl=14thenaf=1:og(112)=0:l=21:goto11327
19107 ifn$="capanna"andl=17thenl=20:goto11327
19129 ifv$="esco"thenprint"{CLEAR}eh!eh!eh!eh!":goto11330
19158 ifn$="lanterna"andl=1andog(126)=0thenprintbj$:og(126)=l:goto11330
19195 ifn$="piccione"andl=1thenprintey$:goto11330
19220 ifn$="merli"andl=3andog(137)=0thenprintby$:og(137)=l:goto11330
19253 ifn$="duna"andl=19andj(19)=0thenprintab$:og(120)=19:goto11330
19284 ifn$="pergamena"thenprintdk$:printdx$:printea$:printeb$:goto11330
19315 ifn$="canna"andl=10andog(134)=0thenprintct$:og(134)=l:goto11330
19348 ifn$="erbacce"andl=20thenprinted$:og(123)=l:goto11330
19376 ifn$="siepe"andl=15andog(121)=0thenprintad$:printae$:og(121)=15:goto11330
19412 ifn$="sirena"andog(120)<>0thenprintap$:goto11330
19437 ifn$="botte"andog(102)=0thenprintcu$:og(102)=l:goto11330
19466 ifn$="acqua"andl=28andog(129)=0thenprintcy$:og(129)=l:goto11330
19499 ifn$="fiaschetta"thenprintcj$:goto11330
19522 ifn$="sacchetto"thenprintdb$:goto11330
19544 ifn$="tomba"andl=18andog(140)=0thenprintak$:og(140)=18:goto11330
19577 ifn$="worm"andl=11andog(80)=11thenprintba$:goto11330
19604 ifn$="orto"andl=20andog(145)=0thenprintdr$:og(145)=l:goto11330
19636 ifn$="quercia"andl=21andj(21)=1andaf=0thenprintdi$:og(112)=l:goto11330
19674 ifn$="puddlefoot"andog(104)=lthenprintdq$:goto11330
19704 ifn$="biglietto"thenprintbn$:printbo$:goto11330
19729 ifn$="luci"andl=5thenprintfd$:goto11330
19749 ifn$="alberelli"andl=5thenprintds$:goto11330
19775 ifn$="prato"andl=5andog(146)=0thenprintdt$:og(146)=l:goto11330
19808 ifn$="salice"andl=5thenprintdz$:goto11330
19830 ifn$="scogliera"andl=13thenprintcg$:og(106)=l:goto11330
19861 ifn$="pietra"andl=13thenprintch$:goto11330
19883 ifn$="forziere"andl=6andai=0thenprintfc$:goto11330
19912 ifn$="cosa"andl=5andog(139)=0thenprintfe$:og(139)=l:goto11330
19944 ifn$="pagliericcio"andl=17thenprintec$:goto11330
19973 ifn$="canneto"andj(23)=0thenprintca$:printbx$:og(104)=l:goto11330
20006 ifn$="nebbia"andl=16thenprintee$:pc=1:goto11330
20031 ifn$="mappa"andog(124)=-1goto31145
20051 ifn$="rovi"andl=24andog(128)=0thenprintai$:og(128)=l:goto11330
20083 ifn$="altare"andl=24andog(133)=0thenprintan$:og(133)=l:goto11330
20117 ifn$="carrello"andl=36andj(36)=0thenprintfg$:og(136)=l:goto11330
20155 ifn$="camino"andl=32andog(131)=0thenprintbo$:og(131)=l:goto11330
20190 ifn$="orme"thenprint"{CLEAR}sono impronte di nano":goto11330
20228 ifn$="galleria"andl=36thenprintfl$:og(143)=l:goto11330
20259 ifn$="cannone"andl=10thenprintef$:goto11330
20282 ifn$="quercia"andl=21andog(110)=lthenprintdl$:goto11330
20312 ifn$="tronco"andl=21andog(110)=lthenprintdl$:goto11330
20341 ifn$="cubo"andl=31thenprintei$:goto11330
20361 ifn$="facce"andl=31andog(148)=0thenprintel$:og(148)=l:goto11330
20394 ifn$="libro"thenprintem$:goto11330
20411 ifn$="scala"andl=34andog(142)=0thenprintep$:og(142)=l:goto11330
20445 ifn$="vaso"andl=34andog(149)=0thenprinteq$:og(149)=l:goto11330
20478 ifn$="forziere"andl=6andai=1thenprintfs$:goto11330
20507 ifn$="knowe"andl=16thenprintfk$:goto11330
20528 ifn$="pozzo"andl=29thenprinter$:goto11330
20549 ifn$="cofanetto"andl=29andj(29)=0thenprintes$:goto11330
20581 ifn$="cofanetto"andl=29andj(29)=1thenprintet$:og(150)=l:goto11330
20618 ifn$="cofanetto"andl=29andj(29)=2thenprinteu$:goto11330
20650 ifn$="tesoro"andl=29thenprintev$:goto11330
20672 ifn$="luci"andl=14orn$="luci"andl=21thenprintfu$:goto11330
20705 ifn$="botola"andl=14thenprintfv$:goto11330
20727 ifn$="bussola"andl=14thenprintfy$:goto11330
20750 ifn$="bussola"goto25901
20764 ifv$="esamino"thenprint"{CLEAR}nulla di rilevante!":goto11330
20803 ifn$="orme"thenprint"{CLEAR}digita la direzione!":goto11330
20840 ifn$="bussola"andl<>14goto25901
20858 ifv$="seguo"thenprint"{CLEAR}no!meglio di no!":goto11330
20892 ifn$="pietra"andl=13andog(130)=0thenprintci$:og(130)=l:goto11330
20926 ifv$="sposto"thenprint"{CLEAR}se puoi fallo!":goto11330
20959 ifn$="fungo"thenprintcr$:printcs$:og(132)=0:og(110)=0:nk=nk+1:goto11330
20993 ifv$="mangio"thenprint"{CLEAR}buon appetito!":goto11330
21026 ifv$="scavo"thenprint"{CLEAR}scava,scava!":goto11330
21056 ifv$="bevo"thenprint"{CLEAR}prosit!":goto11330
21080 ifn$="botola"andl=14thenprint"{CLEAR}si odono piccole voci!":goto11330
21125 ifn$="door"andl=16thenprint"{CLEAR}si odono suoni e canti!":goto11330
21169 ifv$="origlio"thenprint"{CLEAR}nessun rumore ti giunge!":goto11330
21213 ifn$="redcap"andl=4andog(82)=lthenprintat$:printav$:nk=nk+1:goto11330
21249 ifn$="worm"andl=11andog(80)=11thenprintbd$:goto11330
21276 ifn$="goblin"andl=7andog(98)=lthenprintat$:printav$:nk=nk+1:goto11330
21312 ifn$="spriggan"andl=22andog(101)=lthenprintbv$:printbz$:nk=nk+1:goto11330
21351 ifn$="puddlefoot"thenprintcb$:printcc$:og(104)=0:j(23)=1:og(127)=l:goto11330
21391 ifn$="blackdog"andl=25thenprintbd$:goto11330
21416 ifv$="affronto"thenprint"{CLEAR}non ci provare!":goto11330
21453 ifn$="pagliericcio"andl=17thenprintdu$:og(147)=l:goto11330
21487 ifv$="frugo"thenprint"{CLEAR}inutile azione!":goto11330
21520 ifn$="guanto"andog(128)=-1andaa=1thenprintbs$:ab=1:goto11330
21552 ifv$="infilo"thenprint"{CLEAR}uuuuuuuhhh!":goto11330
21582 ifn$="tesoro"andl=36thenprintfi$:og(136)=0:j(36)=1:goto11330
21615 ifn$="door"andl=36thenprintfi$:og(136)=0:j(36)=1:goto11330
21646 ifn$="tesoro"andl=14thenprintfx$:og(81)=0:og(152)=l:j(14)=1:goto11330
21682 ifn$="door"andl=14thenprintfx$:og(81)=0:og(152)=l:j(14)=1:goto11330
21716 ifv$="cerco"thenprint"{CLEAR}quel che cerchi qui'non e'!":goto11330
21761 ifn$="boshrove"andl=25andog(107)=lthenprintcm$:og(107)=0:j(25)=1:goto11330
21802 ifn$="swelush"andog(114)=27andl=27thenprintfo$:og(114)=0:j(27)=1:goto11330
21841 ifn$="horse"andl=29goto26085
21857 ifn$="thuatta"andog(86)=lthenprintfr$:og(86)=0:ai=1:goto11330
21890 ifv$="grido"thenprint"{CLEAR}questo grido effetto non fa'!":goto11330
21937 ifn$="botola"andl=14andj(14)=0thenprintfz$:og(81)=l:goto11330
21970 ifv$="busso"thenprint"{CLEAR}questa bussata effetto non fa'!":goto11330
22019 ifn$=z1$andl=11andog(122)=-1andog(80)=11thenprintbc$:og(80)=0:goto11330
22055 ifn$=z1$andl=11andog(122)=-1andog(80)=11thenprintbc$:og(80)=0:goto11330
22091 ifn$="mano"andab=1andl=22andog(101)=lthenprintbt$:printbu$
22122 ifn$="mano"andab=1andl=22andog(101)=lthenog(101)=0:goto11330
22155 ifn$=z2$andl=12andog(130)=-1andog(105)=lthenprintcf$:og(105)=0:goto11330
22191 ifn$="croce"andog(140)=-1andl=4andog(82)=lthenprintau$:og(82)=0:goto11330
22232 ifn$="primrose"andog(149)=-1andl=16thenprinteh$:pa=1:goto11330
22268 ifn$="primrose"andog(149)<>-1andl=16thenprinteo$:goto11330
22301 ifv$="mostro"thenprint"{CLEAR}serve a poco quel che mostri!":goto11330
22349 ifn$="guanto"andog(128)=-1thenaa=1:printbr$:goto11330
22377 ifv$="rovescio"thenprint"{CLEAR}che gusti!":goto11330
22409 printpt$
22411 goto11330
22414 ifi$="d"goto11327
22422 ifn$="knowe"goto22868
22434 ifn$="sirena"goto23024
22447 ifn$="leprecaun"goto23151
22464 ifn$="nano"goto23264
22475 ifn$="redcap"goto23393
22488 ifn$="worm"goto23514
22499 ifn$="kelpie"goto23623
22512 ifn$="goblin"goto23752
22525 ifn$="boneless"goto25621
22541 ifn$="duergar"goto25742
22555 ifn$="elfshot"goto23875
22569 ifn$="spriggan"goto23956
22585 ifn$="puddlefoot"goto24078
22603 ifn$="gwyllion"goto24193
22619 ifn$="blackdog"goto24274
22635 ifn$="pixie"goto24378
22647 ifn$="oakman"goto24498
22660 ifn$="cluricaun"goto24586
22677 ifn$="killmoulis"goto24712
22695 ifn$="brownie"goto24816
22709 ifn$="primrose"goto24903
22725 ifn$="ryegrass"goto24950
22741 ifn$="door"goto25049
22752 ifn$="foxglore"goto25210
22768 ifn$="violet"goto25253
22781 ifn$="fourcleaved"goto25293
22800 ifn$="daisy"goto25328
22812 ifn$="ogre"goto25355
22823 ifn$="knocker"goto25473
22837 print"{CLEAR}spiacente,ma non ho dati"
22865 goto11330
22868 print"{CLEAR}{REVERSE ON}KNOWE{REVERSE OFF}: Collina cava,dimora degli esseri"
22913 print"fatati  e nascondiglio dei loro tesori."
22955 print"Se ne cerchi  la door d'ingresso, fallo"
22997 print"in una notte d'agosto"
23021 goto11330
23024 print"{CLEAR}{REVERSE ON}SIRENA{REVERSE OFF}:   Essere mitologico meta' donna"
23069 print"e meta' pesce  che con il suo canto at="
23111 print"tira gli uomini per farli schiavi."
23148 goto11330
23151 print"{CLEAR}{REVERSE ON}LEPRECAUN{REVERSE OFF}:Elfo ciabattino.Devi prender="
23196 print"lo prima che ti veda e ti dira' dove ha"
23238 print"nascosto il suo oro."
23261 goto11330
23264 print"{CLEAR}{REVERSE ON}NANO{REVERSE OFF}: Basso,tarchiato, con lunga barba,"
23309 print"indossa una veste che gli copre i piedi"
23351 print"a zampa d'oca,o girati all'indietro."
23390 goto11330
23393 print"{CLEAR}{REVERSE ON}REDCAP{REVERSE OFF}:Folletto dal berretto rosso di"
23436 print"sangue.Ha artigli e affilatissimi denti"
23478 print"{REVERSE ON}PROTECTION{REVERSE OFF}:Digita p [RETURN]"
23511 goto11330
23514 print"{CLEAR}{REVERSE ON}WORM{REVERSE OFF}:(Vermone) Drago custode di tesori,"
23559 print"squamoso e sputafiele.Attento,ha un so="
23601 print"lo punto debole."
23620 goto11330
23623 print"{CLEAR}{REVERSE ON}KELPIE{REVERSE OFF}: (Cavallo d'acqua)  quando viene"
23668 print"cavalcato corre a tuffarsi nel mare con"
23710 print"tutto il cavaliere che,ahime',crepa."
23749 goto11330
23752 print"{CLEAR}{REVERSE ON}GOBLIN{REVERSE OFF}:Questo folletto usa tutte le sue"
23797 print"arti  per attirare l'incauto viandante!"
23839 print"{REVERSE ON}PROTECTION{REVERSE OFF}:Digita p [RETURN]"
23872 goto11330
23875 print"{CLEAR}{REVERSE ON}ELFSHOT{REVERSE OFF}:(Colpo della strega) pietra ap="
23920 print"puntita lanciata da una stega."
23953 goto11330
23956 print"{CLEAR}{REVERSE ON}SPRIGGAN{REVERSE OFF}: Guardiano del tesoro che puo'"
24001 print"ingigantire a piacere per spaventarti!"
24042 print"{REVERSE ON}PROTECTION{REVERSE OFF}:Digita p [RETURN]"
24075 goto11330
24078 print"{CLEAR}{REVERSE ON}PUDDLEFOOT{REVERSE OFF}:  (Piede melmoso) vaga negli"
24123 print"stagni  inzaccherandosi i lunghi piedi."
24165 print"E' timido e permaloso."
24190 goto11330
24193 print"{CLEAR}{REVERSE ON}GWYLLION{REVERSE OFF}:   Spirito femminile malvagio."
24238 print"{REVERSE ON}PROTECTION{REVERSE OFF}:Digita p [RETURN]"
24271 goto11330
24274 print"{CLEAR}{REVERSE ON}BLACKDOG{REVERSE OFF}: Cane nero,irsuto,con artigli,"
24319 print"occhi rossi e corna!"
24342 print"{REVERSE ON}PROTECTION{REVERSE OFF}:Digita p [RETURN]"
24375 goto11330
24378 print"{CLEAR}{REVERSE ON}PIXIE{REVERSE OFF}: Folletto verde assai dispettoso,"
24423 print"con occhi strabici e naso all'insu'."
24462 print"{REVERSE ON}PROTECTION{REVERSE OFF}:Digita p [RETURN]"
24495 goto11330
24498 print"{CLEAR}{REVERSE ON}OAKMAN{REVERSE OFF}:  Folletto delle quercie. Atten="
24543 print"to,spaccia funghi velenosi per buoni."
24583 goto11330
24586 print"{CLEAR}{REVERSE ON}CLURICAUN{REVERSE OFF}:Folletto abitatore delle can="
24631 print"tine. Ha il berretto rosso,le calze az="
24673 print"zurre e le scarpe col tacco alto."
24709 goto11330
24712 print"{CLEAR}{REVERSE ON}KILLMOULIS{REVERSE OFF}:Elfo dei mulini. E' privo di"
24757 print"bocca.Ha un grande naso nel quale infi="
24799 print"la il cibo."
24813 goto11330
24816 print"{CLEAR}{REVERSE ON}BROWNIE{REVERSE OFF}:(Brunetto) elfo domestico. Puo'"
24861 print"non aver dita, puo'non aver naso...."
24900 goto11330
24903 print"{CLEAR}{REVERSE ON}PRIMROSE{REVERSE OFF}:(Primula)fiore assai fatato!!"
24947 goto11330
24950 print"{CLEAR}{REVERSE ON}RYEGRASS{REVERSE OFF}:(Loglierello) fiore fatato,che"
24995 print"gridando una parola magica, consente di"
25037 print"volare!"
25046 goto11330
25049 print"{CLEAR}{REVERSE ON}DOOR{REVERSE OFF}:Porta del tesoro. Per aprirla pro="
25094 print"va a mostrarle un fiore fatato,oppure a"
25136 print"bussarci  un certo numero di volte, o a"
25178 print"gridare una parola magica!"
25207 goto11330
25210 print"{CLEAR}{REVERSE ON}FOXGLORE{REVERSE OFF}: (Digitale) fiore fatato."
25250 goto11330
25253 print"{CLEAR}{REVERSE ON}VIOLET{REVERSE OFF}:(Violetta) fiore fatato."
25290 goto11330
25293 print"{CLEAR}{REVERSE ON}FOURCLEAVED{REVERSE OFF}:(Quadrifoglio)"
25325 goto11330
25328 print"{CLEAR}{REVERSE ON}DAISY{REVERSE OFF}:(Margherita)"
25352 goto11330
25355 print"{CLEAR}{REVERSE ON}OGRE{REVERSE OFF}:(Orco) essere orribile, con lunghi"
25400 print"denti e tendenza all'antropofagia!"
25437 print"{REVERSE ON}PROTECTION{REVERSE OFF}:Digita p [RETURN]"
25470 goto11330
25473 print"{CLEAR}{REVERSE ON}KNOCKER{REVERSE OFF}:  (Picconatore)  folletto delle"
25518 print"miniere che  usa picconare nel punto in"
25560 print"cui si trova un filone!E'innocuo e ser="
25602 print"vizievole...."
25618 goto11330
25621 print"{CLEAR}{REVERSE ON}BONELESS{REVERSE OFF}: (Senz'ossa)  creatura viscida"
25666 print"e informe,simile a una grossa medusa."
25706 print"{REVERSE ON}PROTECTION{REVERSE OFF}:Digita p [RETURN]"
25739 goto11330
25742 print"{CLEAR}{REVERSE ON}DUERGAR{REVERSE OFF}: (Nano malvagio) pericolosissi="
25787 print"mo e astuto nemico dei viandanti...."
25826 print"{REVERSE ON}PROTECTION{REVERSE OFF}:Digita p [RETURN]"
25859 goto11330
25862 x1=int(3*rnd(1)+1)
25871 ifx1=1thenj(15)=1:goto16486
25884 ifx1<>1thenprintaf$:og(121)=0:goto11330
25901 x3=int(4*rnd(1)+1)
25910 onx3goto25922,25933,25943,25953
25922 printgn$;
25924 print"nord"
25930 goto25962
25933 printgn$;
25935 print"est"
25940 goto25962
25943 printgn$;
25945 print"sud"
25950 goto25962
25953 printgn$;
25955 print"ovest"
25962 goto11330
25965 print"{CLEAR}Appena entrato nella door,senti delle"
26006 print"risate agghiaccianti,poi cadi!Cadi sem="
26048 print"pre piu' in basso,finche'...."
26080 l=29
26082 goto11330
26085 poke53265,27
26093 print"{CLEAR}Ed ecco che il magico fiore ti trascina"
26136 print"verso l'alto,verso l'orifizio del pozzo"
26178 print"che si fa' sempre piu' grande!...Sempre"
26220 print"piu' grande!...finche' sei salvo!...."
26260 print"Salvo e.... se non hai dimenticato  nel"
26302 print"pozzo il tesoro di shagaboo.... favolo="
26344 print"samente riccoooooo!!!!"
26369 tt=1
26371 fortt=1to14
26376 print
26377 next
26378 poke19,0
26381 end
26382 end
26383 ab$="{CLEAR}c'e' una sirena arenata"
26411 ac$="{CLEAR}devi prendere la sirena"
26439 ad$="{CLEAR}c'e' un leprecaun che lavora febbril="
26481 ae$="mente alla sua scarpa"
26506 af$="{CLEAR}non puoi,t'ha visto prima lui!"
26541 ag$="{CLEAR}ti supplica:she me lassi 'ndar nti"
26580 ah$="svelush dowe est tresor!"
26608 ai$="{CLEAR}c'e' impigliato un guanto"
26638 al$="{CLEAR}il goblin ti dice:kuel che sherchi no"
26680 am$="aqui' ma bekk this map and truovarre'!"
26722 an$="{CLEAR}trovi una campanella"
26747 ao$="{CLEAR}troppo pesante per portarla via"
26783 ap$="{CLEAR}la sirena e' agonizzante!"
26813 ar$="{CLEAR}il redcap te lo impedisce!"
26844 as$="{CLEAR}il goblin te lo impedisce!"
26875 at$="{CLEAR}un elfshot ti colpisce  e svieni per"
26916 au$="{CLEAR}il redcap fugge urlando!"
26945 av$="un'ora!...."
26960 ax$="{CLEAR}ti dice:vahtten intrush!"
26989 ay$="{CLEAR}vedi i resti d'una tomba"
27018 ak$="{CLEAR}sulla tomba c'e' una croce"
27049 aj$="{CLEAR}non puoi,c'e' lo worm!"
27076 ba$="{CLEAR}e' orribile da vedersi!"
27104 bb$="{CLEAR}ti dice:farin nn'she' piu'!shuuuuu!"
27144 bc$="{CLEAR}nel vedersi lo worm fugge impaurito!"
27185 bd$="{CLEAR}perche' vuoi morire?"
27210 be$="{CLEAR}il cavallo  e' un kelpie, che, dopo una"
27254 bf$="lunga corsa si tuffa in mare,e ora...."
27296 bg$="{CLEAR}hai perso i sensi.  ma la sirena che a="
27340 bh$="vevi salvato  e' ben felice di renderti"
27383 bi$="il favore,e ti porta a riva"
27414 bl$="dopo un'ora rinvieni e...."
27444 bm$="{CLEAR}lo spriggan ti blocca!"
27471 bo$="{CLEAR}c'e' del pane secco"
27495 bp$="{CLEAR}il goblin l'afferra e fugge contento!"
27537 bq$="{CLEAR}c'e' uno spriggan in agguato!"
27571 br$="{CLEAR}l'hai rovesciato"
27592 bs$="{CLEAR}l'hai infilato"
27611 bt$="{CLEAR}alla vista del guanto rovesciato lo"
27651 bu$="spriggan fugge!"
27670 bv$="{CLEAR}lo spriggan diviene gigantesco!ti col="
27713 bz$="pisce e svieni per un'ora!...."
27747 bx$="sta' mangiando qualcosa"
27774 bj$="trovi un chiodo"
27793 by$="{CLEAR}su un merlo c'e' una chiave"
27825 ca$="{CLEAR}fra le canne c'e' un puddlefoot che"
27865 cb$="{CLEAR}il puddlefoot fugge lasciando in ter="
27907 cc$="ra del pasticcio d'oca...."
27937 ce$="{CLEAR}la gwyllion ti blocca!"
27964 cf$="{CLEAR}la gwyllion vede il coltello e fugge!"
28006 cg$="{CLEAR}vedi una grossa pietra bianca"
28040 ch$="{CLEAR}c'e' scritto:for black:boshrove"
28076 ci$="{CLEAR}trovi un coltello"
28098 cl$="{CLEAR}un blackdog ti sbarra il passo!"
28134 cm$="{CLEAR}il blackdog fugge guaendo!"
28165 cn$="{CLEAR}il pixie te lo impedisce!"
28195 co$="{CLEAR}il pixie prende il pane e fugge!"
28232 cp$="{CLEAR}l'oakman ti dice:bekk kuell fungh,"
28271 cq$="ish kuntravelen...."
28294 cr$="{CLEAR}il fungo ha poteri soporiferi quindi"
28335 cs$="dormi per un'ora!...."
28360 ct$="{CLEAR}c'e' dentro una bacchetta"
28390 cu$="{CLEAR}sulla botte salta un cluricaun"
28425 cv$="{CLEAR}il sacchetto,magicamente,scoppia"
28462 cz$="{CLEAR}ti dice:mmmummm,bott vuott!...."
28498 cy$="{CLEAR}nell'acqua c'e' una fiaschetta"
28533 cj$="{CLEAR}e' sigillata e piena di vino!"
28567 cx$="{CLEAR}dalla fiaschetta esce un gas sopori="
28608 ck$="fero e tu,incauto,dormi per un'ora!...."
28651 da$="cadi stordito e rinvieni dopo un'ora!"
28692 db$="{CLEAR}e' sigillato e pieno di farina"
28727 dc$="{CLEAR}ti dice:mmmummm,farin non ghiet...."
28767 dd$="{CLEAR}il cluricaun prende la fiaschetta di"
28808 df$="vino e ti regala un flauto"
28838 dg$="{CLEAR}il killmoulis prende il sacchetto di"
28879 dh$="farina e ti regala un nastro rosso"
28917 di$="{CLEAR}alla base del tronco c'e' un'apertura!"
28960 dl$="{CLEAR}piccole luci le svolazzano attorno"
28999 dn$="{CLEAR}il brownie ti dice:shagaboo yes!"
29036 do$="{CLEAR}il brownie divora la focaccia e dice:"
29078 dp$="shagaboo yes yes yes!"
29103 dq$="{CLEAR}sta' mangiando qualcosa"
29131 dr$="{CLEAR}in un remoto angolo c'e' un foxglore"
29172 ds$="{CLEAR}strane luci si muovono fra di loro"
29211 dt$="{CLEAR}vedi una splendida violet"
29241 du$="{CLEAR}trovi una pergamena"
29265 dz$="{CLEAR}freme e scricchiola!...."
29294 dk$="{CLEAR}c'e' scritto:{REVERSE ON} for blow: thuatta "
29332 dx$="             {REVERSE ON} for knock:gwollak "
29369 ea$="             {REVERSE ON} for sweep:swelush "
29406 ec$="{CLEAR}qualcuno ci ha dormito da poco"
29441 ed$="{CLEAR}fortunato!trovi un fourcleaved!"
29477 ee$="{CLEAR}in un punto dirada e vedi una door!"
29517 ef$="{CLEAR}e' del xvii secolo,senza ruote"
29552 eg$="{CLEAR}una forza misteriosa te l'impedisce!"
29593 eh$="{CLEAR}la door s'e' aperta!"
29618 ei$="{CLEAR}e' simile a un enorme dado da gioco"
29658 el$="{CLEAR}una faccia e' cava e contiene un libro"
29701 em$="{CLEAR}il titolo e':shagaboo yes"
29731 en$="{CLEAR}e' cavo e contiene una primrose!"
29768 eo$="{CLEAR}devi avere anche un altro fiore con te!"
29812 ep$="{CLEAR}sotto la scala c'e un vaso da fiori"
29852 eq$="{CLEAR}nel vaso e' piantato un ryegrass!"
29890 er$="{CLEAR}le sue pareti non offrono appigli!"
29929 es$="{CLEAR}e' socchiuso...."
29950 et$="{CLEAR}c'e' il tesoro di shagaboo!"
29982 eu$="{CLEAR}sul fondo c'e' scritto:for sky:horse"
30023 ev$="{CLEAR}e' favolosamente indescrivibile!"
30060 ej$="{CLEAR}hai aperto il cofanetto!"
30089 ey$="{CLEAR}ha qualcosa legata alla zampina...."
30129 ek$="{CLEAR}si ode un urlo e appare un ogre che ti"
30172 ex$="dice:pussha via!pussha via!grrrrrrr!"
30212 fa$="{CLEAR}l'ogre te l'impedisce!"
30239 fc$="{CLEAR}e' blindato,con serratura"
30269 fd$="{CLEAR}sono concentrate su una cosa rotonda"
30310 fe$="{CLEAR}la cosa e' una focaccia!"
30339 ff$="{CLEAR}non si lascia prendere!"
30367 fg$="{CLEAR}dal carrello sbuca fuori uno knocker!"
30409 fh$="{CLEAR}ti chiede:cuossa sherchi?"
30439 fi$="{CLEAR}ti risponde:qui shercha truova! ciao!"
30481 fm$="{CLEAR}la boneless ti sbarra il passo!"
30517 fo$="{CLEAR}la boneless viene spazzata via!"
30553 fp$="{CLEAR}il duergar ti blocca!"
30579 fq$="{CLEAR}il duergar fugge a tutta birra!"
30615 fr$="{CLEAR}l'ogre becca una mazzata e fugge!"
30653 fs$="{CLEAR}ahime',e' vuoto!...."
30678 fu$="{CLEAR}emettono deboli squittii!"
30708 fv$="{CLEAR}e' metallica,senza serratura"
30741 fz$="{CLEAR}un nano appare davanti a te!"
30774 fx$="{CLEAR}ti dice:alor shegui esta buxxola!"
30812 fj$="{CLEAR}il nano ti chiede:cuossa cherch tu?"
30852 fy$="{CLEAR}l'ago vibra in modo strano...."
30887 fk$="{CLEAR}c'e' molta nebbia attorno a te."
30923 return
30924 end
30925 print"{CLEAR}la sirena ti dice: stanott est the nott"
30968 print"in kui qui scerka truova!tu scerka door"
31010 print"of tresor....thank you and ciao!...."
31049 j(19)=1
31053 ag=0
31055 goto11330
31058 print"{CLEAR}il leprecaun ti dice: cerch orme dellu"
31100 print"nano,seghuile,and....poi sparisce!"
31137 og(113)=20
31142 goto11330
31145 print"{CLEAR}eccola:"
31156 print"        {REVERSE ON}         TREASURE{SH SPACE} MAP         "
31199 print"        {REVERSE ON}   N                           "
31242 print"        {REVERSE ON}   {SH -}    !! ??{ARROW LEFT} Tower           "
31285 print"        {REVERSE ON} W{SH ASTERISK} {SH ASTERISK}E        {^}     ? Cemetery "
31328 print"        {REVERSE ON}   {SH -}     ! {ARROW LEFT} {ARROW LEFT} {ARROW LEFT} {ARROW LEFT} {ARROW LEFT} {ARROW LEFT} {ARROW LEFT} ???   "
31371 print"        {REVERSE ON}   S                      {ARROW LEFT}    "
31414 print"        {REVERSE ON}       ? Wood  Knowe  Church{^}  "
31457 print"        {REVERSE ON}   {^}          {^}             {^}{SH SPACE} "
31500 print"        {REVERSE ON}   ?Cave   Tunnel  {ARROW LEFT}  Mine  {CM X}  "
31543 goto11330
31546 print"{CLEAR}{REVERSE ON}       Protection Against Fairies      "
31590 print
31591 print"Consigli ai notturni  incauti viandanti"
31633 print"che si trovassero in presenza di esseri"
31675 print"fatati:"
31684 print"In genere  e' sufficiente  mostrare col"
31726 print"telli,chiodi,ferri di cavallo,aghi,cro="
31768 print"ci,specchi,nastri rossi,corna,quadrifo="
31810 print"gli,margherite,bacchette di gelso,ecc."
31851 print"o spargere  sale, o indossare indumenti"
31893 print"alla rovescia...."
31913 print"Provate a  gridare frasi magiche, se ne"
31955 print"conoscete,o suonate campanelle!"
31989 print"provate pure ad offrire focacce,pastic="
32031 print"ci d'oca,pane secco,farina,vino,ecc."
32070 print"Al contrario,non accettate ne' cibi ne'"
32112 print"bevande,e,specie di notte,camminate al="
32154 print"la larga da quercie,salici,sambuchi,be="
32196 print"tulle e ontani...."
32217 print"{HOME}{DOWN}{DOWN}{DOWN}{DOWN}{DOWN}{DOWN}{DOWN}{DOWN}{DOWN}{DOWN}{DOWN}{DOWN}{DOWN}{DOWN}{DOWN}{DOWN}{DOWN}{DOWN}{DOWN}"
32240 print"             {REVERSE ON}premi un tasto per giocare"
32283 poke53265,27
32291 getk$
32294 ifk$=""goto32291
32301 poke53265,11
32309 goto11327
32312 end
32323 data"n","e","s","o","i","f","r","t","d","v","p","affronto","apro"
32333 data"bevo","busso","cerco","entro","esamino","esco","frugo","grido"
32343 data"immergo","infilo","lascio","leggo","mangio","monto","mostro"
32353 data"offro","origlio","parlo","prendo","rovescio","salgo","saluto"
32363 data"scavo","scendo","seguo","sposto","suono","uso",0,"terrazzino"
32373 data"
290 ","dfaro
