
start tok64 am-ready.prg
10 FORa=1TO300:NEXT:CLR
20 POKE774,93:DIMkj$(32):GOSUB1900:GOSUB2800
40 POKE53280,6:POKE53281,6:PRINT"{green}":GOSUB52000:GOSUB2440
60 GOSUB2360:PRINT"{home}{down*5}{right*2}abbisognate de insegnamento ?"
65 GETa$:IFa$<>"s"ANDa$<>"n"THEN65
66 IFa$="s"THENGOSUB5000
70 GOSUB2360:PRINT"{home}{down*10}{right*3}numero delli giuocatori ";:GOSUB30000:g$=in$
75 g%=VAL(g$):IFg%>9ORg%<1THEN70
80 GOSUB2120:FORa=1TOg%:s(a)=1000:ss(a)=1000:p1(a)=1:p2(a)=1:g(a)=10000
81 te(a)=500:NEXT
100 FORa=1TOg%
120 GOSUB2360:r=INT(RND(1)*te(a)*75):p=INT((1-r/te(a)/75)*60)+1:r$=STR$(r)
140 PRINT"{right}croniche historiche dello anno"900+q:cn=0
160 PRINT"{down}{right*2}"t$(t(a))" "n$(a)
180 d=INT((RND(1)*2+1)*ss(a)):us=INT((1-r/te(a)/75)*40):us$=STR$(us)
200 PRINT"{down}{right}raccolto{space*7}{left*7}"r$
220 PRINT"{down}{right}frumento{space*7}{left*7}"INT(g(a))
240 PRINT"{down}{right}dimanda{space*7}{left*6}"INT(d)
260 PRINT"{down}{right}costo{space*9}{left*6}"p:PRINT"{down}{right}scudi{space*10}{left*7}"INT(s(a))
270 PRINT"{down}{right}usura{space*10}{left*7}"us$" %":PRINT"{down}{right}acri{space*11}{left*7}"te(a)
280 PRINT"{down}{right}servi{space*9}{left*6}"ss(a):GOSUB2580:IFcn=1THEN420
300 PRINT"{home}{down*6}"SPC(18):FORt=1TO15:PRINTSPC(39)"{cm n}";:NEXT
320 PRINTSPC(39)"{sh @}{home}{down*7}"SPC(24);:IFcn<>2THENPRINT"delibera":GOTO380
340 PRINT"{left}nello anno{space*4}":PRINTSPC(19)"{down}{space*15}":PRINTSPC(19)"{down}{space*16}"
360 PRINTSPC(19)"{down}{space*20}":PRINTSPC(19)"{down}{space*20}":GOTO700
380 PRINTSPC(59)"1.a comperare"SPC(67)"2.a vendere"SPC(69)"3.a nutrire li servi";
400 PRINTSPC(61)"oprate una scelta"
420 GETa$:i=VAL(a$):IFi<1ORi>3THEN420
440 ONiGOTO460,540,620
460 PRINT"{home}{down*18}"SPC(20)"{reverse on}grano a comprarsi{reverse off}"SPC(63);:GOSUB30000
470 i$=in$:IFi$="@"THENPRINT"{home}{down*5}":cn=1:GOTO200
475 IFs(a)<-tt(a)THEN520
480 i=VAL(i$):IFi>VAL(r$)THEN520
490 s=INT(s(a)-i*p/1000):IFs<-tt(a)THEN460
500 cn=1:g(a)=g(a)+i:s(a)=s:r$=STR$(VAL(r$)-i)
520 PRINT"{home}{down*5}":cn=1:GOTO200
540 PRINT"{home}{down*18}"SPC(20)"{reverse on}grano a vendersi{reverse off} "SPC(63);:GOSUB30000
550 i$=in$:IFi$="@"THENPRINT"{home}{down*5}":cn=1:GOTO200
560 i=VAL(i$):IFg(a)-i<0THEN540
580 g=g(a)-i:s=s(a)+i*p/1000:PRINT"{home}{down*5}":IFs(a)<-2500THEN540
600 g(a)=g:s(a)=s:cn=1:GOTO200
620 PRINT"{home}{down*18}"SPC(18)"{reverse on}largimento alli servi{reverse off}"SPC(63);:GOSUB30000
630 i$=in$:IFi$="@"THENPRINT"{home}{down*5}":cn=1:GOTO200
660 s=VAL(i$):IFs>g(a)THEN620
670 f=INT(RND(1)*((ss(a)/90*29)*(s-d)/10000)):g(a)=g(a)-s
680 s1=ss(a):ss(a)=ss(a)+f:cn=2:IFss(a)<0THENf=-s1:ss(a)=0
690 PRINT"{home}{down*5}":r$=" {-*5}":GOTO200
700 PRINT"{home}{down*6}":IFf>=0THENa$="sono{space*2}nati"
720 IFf<0THENa$="sono{space*2}morti"
740 PRINT"{down}"SPC(23)a$:PRINT"{down}"SPC(23)ABS(f)"servi"
760 PRINT"{down*3}"SPC(23)"uno tasto par":PRINTSPC(64)"lo sequito"
780 GOSUB1860:kj=INT(RND(1)*32+1):kj$=kj$(kj):IFkj$=""THEN800
781 GOSUB2360:PRINT"{down}{right}{space*6}accadimento{space*3}mirabilis"
782 PRINT"{right*2}AXAXAXAXAXAXAXAXAXAXAXAXAXAXAXAXAXAX{down*3}":IFRIGHT$(kj$,1)="%"THEN787
784 IFRIGHT$(kj$,1)="?"THEN789
785 PRINT"{down*3}"LEFT$(kj$,LEN(kj$)-1):de=VAL(RIGHT$(kj$,5)):IFRIGHT$(kj$,1)="-"THENde=-de
786 s(a)=s(a)+de:GOTO799
787 PRINT"{down*3}"LEFT$(kj$,LEN(kj$)-4);:de=VAL(RIGHT$(kj$,3)):de=INT(de*ss(a)/100)
788 ss(a)=ss(a)-de:PRINTde:GOTO799
789 PRINT"{home}{down*11}"kj$:GOSUB1860:IFa$<>"p"ANDa$<>"r"THEN789
790 in=INT((RND(1)*1600+1)-800):de=INT((RND(1)*100+1)-50)
791 IFa$="p"THEN793
792 in=ABS(in):s(a)=s(a)-in:PRINT"{down}{right*2}pagati"in"scudi":GOTO799
793 s(a)=s(a)+in:ss(a)=ss(a)+de:IFin<0THENPRINT"{down}{right*2}espesi"ABS(in)"scudi"
794 IFin>0THENPRINT"{down}{right*2}sacco di"ABS(in)"scudi"
795 IFde<0THENPRINT"{down}{right*2}perduti"ABS(de)"servi"
796 IFde>0THENPRINT"{down}{right*2}si fecero"ABS(de)"servi"
799 GOSUB1860
800 GOSUB2360:PRINT"{space*12}r e n d i t e"
820 PRINT"{down}{right}{A*38}"
840 PRINTSPC(19);:FORt=1TO15:PRINTSPC(39)"B";:NEXT
860 PRINT"{home}{down*7}{right}{space*3}{reverse on}commerzio{reverse off}"SPC(13)"{reverse on}gabella{reverse off}"
865 g(a)=INT(g(a)-g(a)/(RND(1)*8+2))
880 l1=INT(n(a)*da(a)/500):IFl1<0THENl1=0
890 IFp1(a)>1THENPRINT"{right*2}{down}mercati{space*7}{left*7}"l1
900 l2=INT(v(a)*da(a)/500):IFl2<0THENl2=0
905 IFp2(a)>1THENPRINT"{right*2}{down}opifizi{space*7}{left*7}"l2
910 PRINT"{home}{down*13}{right}";:FORhh=1TO17:PRINT"{sh asterisk}";:NEXT
915 PRINT"{home}{down*14}{right}{space*3}{reverse on}vassalli {reverse off}":IFva(a)<>0THENPRINT"{down}{right} "va(a)" scudi"
917 PRINT"{home}{down*19}{right}";:FORhh=1TO17:PRINT"{sh asterisk}";:NEXT
940 c=ac(a)+pa(a)+da(a):IF180-c<0THENc=180/c:GOTO980
960 c=1
980 ac=INT((ss(a)*ac(a)/100)/5):da=l1+l2
990 IFss(a)>0THENpa=INT((s*2*pa(a)/ss(a)))
991 IFss(a)=0THENpa=0
1000 l=INT((ac+da+pa)*c):PRINT"{home}{down*9}"SPC(23)"scudi{space*7}{left*6}"l
1020 PRINTSPC(59)"1. bevere{space*9}{left*5}"ac(a)"%"
1040 PRINTSPC(19)"{down}2. macina{space*9}{left*5}"pa(a)"%"
1060 PRINTSPC(19)"{down}3. commerzio{space*6}{left*5}"da(a)"%"
1080 PRINTSPC(19)"{down}4. bastante{space*6}"
1100 PRINT"{reverse on}{down}"SPC(21)"{reverse on}oprate un scelta{reverse off}"
1120 tt(a)=l+va(a)
1140 IFva(a)<>0THENPRINT"{home}{down*21}{right}in toto{space*7}{left*7}"tt(a)"{up*2}"
1160 GETa$:i=VAL(a$):IFi<1ORi>4THEN1160
1180 IFi=4THENs(a)=s(a)+l:GOTO1340
1200 PRINT"{up}"SPC(21)"{space*18}"
1220 PRINT"{up}"SPC(21)"{space*2}{reverse on}quanto{reverse off} ";:GOSUB30000:i$=in$:f=VAL(i$)
1240 IFf>99THEN1220
1260 ONiGOTO1280,1300,1320,1340
1280 ac(a)=f:GOTO860
1300 pa(a)=f:GOTO860
1320 da(a)=f:GOTO860
1335 s(a)=s(a)+tt(a):va(a)=0
1340 GOSUB2360:PRINT"{right}{space*8}l o{space*5}r e a m e "
1360 PRINT"{down}{right}ASASASASASASASASASASASASASASASASASASAS"
1380 PRINT"{down}{right*2}{reverse on}a.d."900+q"{reverse off} "
1400 PRINT"{down}{right}{reverse on}"t$(t(a))" {reverse on}"n$(a)
1420 PRINT"{down*2}{right*2}"LEFT$(p$,p1(a))
1440 PRINT"{down}{right*2}"LEFT$(c$,p2(a))
1460 PRINT"{down*3}{right*5}{reverse on}"LEFT$(ca$,p3(a)*13):GOSUB1860
1480 GOSUB2360:PRINT"{right*2}{space*3}d i s p e n d i m e n t i{space*2}"
1500 PRINT"{down}{right}XSXSXSXSXSXSXSXSXSXSXSXSXSXSXSXSXSXSXS"
1520 PRINT"{home}{down*7}{right*2}{space*3}costum{space*15}possessi{up}"
1530 PRINT"{down}{right}1. 25 acri{space*4}500{space*2}"SPC(9)te(a)
1540 PRINT"{down}{right}2. mercatum{space*2}2{0*3}{space*2}"SPC(9)p1(a)-1
1560 PRINT"{down}{right}3. opifitium 5{0*3}{space*2}"SPC(9)p2(a)-1
1580 PRINT"{down}{right}4. palatium 1{0*4}{space*2}"SPC(9)p3(a)
1600 PRINT"{down}{right}5. karta{space*7}-{space*6}6. proximus"
1640 PRINT"{down}{right*10}{reverse on} oprate una scelta {reverse off}":s(a)=INT(s(a))
1660 PRINT"{down}{right}thesauro della signoria{space*15}{left*15}"s(a)"scudi"
1680 GOSUB1860:i=VAL(a$):IFi>6ORi<1THEN1680
1700 in%=INT(te(a)-500)/500
1720 ONi GOTO1725,1740,1780,1820,1340,1960
1725 IFte(a)=2000ORs(a)-500<-tt(a)THEN1680
1730 te(a)=te(a)+25:s(a)=s(a)-500:GOTO1520
1740 IFp1(a)=20+in%ORs(a)-2000<-tt(a)THEN1680
1760 p1(a)=p1(a)+1:s(a)=s(a)-2000:GOTO1520
1780 IFp2(a)=20+in%ORs(a)-5000<-tt(a)THEN1680
1800 p2(a)=p2(a)+1:s(a)=s(a)-5000:GOTO1520
1820 IFp3(a)=11ORs(a)-10000<-tt(a)THEN1680
1840 p3(a)=p3(a)+1:s(a)=s(a)-10000:GOTO1520
1860 GETa$:IFa$=""THEN1860
1880 RETURN
1900 p$=" {Z*19}":c$=" {W*19}"
1920 ca$="ZX{right*2}AS{down}{left*6} #{space*2}# {down}{left*6} {#*4} {reverse off*7}{cm @*2}{cm i*2}{cm @}{sh @}{up}{left*6}O{cm t}{cm asterisk}{sh pound}{cm t}P{up}{left*6}{sh pound}{cm asterisk}{right*2}{sh pound}{cm asterisk}"
1940 RETURN
1960 n(a)=INT((p1(a)-1)*ss(a))
1965 s1=ss(a)-s1+2:IFs1=0THENs1=1e-20
1970 k=ss(a)/s1:k1=SGN(k):IFs(a)<0THENs(a)=s(a)+INT(us/100*s(a))
1975 k=ABS(k):k=SQR(k):k=(1-(k-INT(k)))*k1
1980 v(a)=INT((3*p2(a)-3)*ss(a)*k)
2000 ka=(p1(a)-1)*2000+(p2(a)-1)*5000+(te(a)-500)/25*500+p3(a)*10000+s(a)
2020 IFka>10000THENt(a)=1+ll(a)
2040 IFka>50000THENt(a)=2+ll(a)
2060 IFka>95000THENt(a)=3+ll(a)
2070 IFka>160000THENt(a)=4+ll(a)
2080 IFka>367000THEN2600
2083 va(a)=0:pj=t(a):IFpj>5THENpj=pj-5
2085 FORy=1TOg%:py=t(y):IFpy>5THENpy=py-5
2090 dy=pj-py:IFdy>0THENva(a)=va(a)+100*dy:s(y)=s(y)-100*dy
2100 NEXT:NEXT:q=q+1:GOTO100
2120 FORa=1TO10:READt$(a):NEXT
2140 FORa=1TOg%:READa$:GOSUB2360:PRINT"{down*3}a chi lo feudo de "a$" ";
2160 GOSUB30000:n$=in$
2180 n$(a)=n$+" da {sh space}"+a$
2200 PRINT"{down*3}{right*3}madonna o cavaliere ?"
2220 GETt$:IFt$<>"m"ANDt$<>"c"THEN2220
2240 ll(a)=1:IFt$="m"THENll(a)=6
2260 t(a)=ll(a):NEXT:RETURN
2280 DATAmesser,conte,duca,gr.duca,principe
2300 DATAmadonna,contessa,duchessa,gr.duchessa,principessa
2320 DATA"{reverse on}bugella{reverse off}","{reverse on}genua{reverse off}","{reverse on}roma{reverse off}","{reverse on}venetia{reverse off}","{reverse on}neapolis{reverse off}"
2340 DATA"{reverse on}florentia{reverse off}","{reverse on}eporediae{reverse off}","{reverse on}taurinum{reverse off}","{reverse on}mediolanum{reverse off}"
2360 PRINT"{clear}A{space*18}A{space*19}A";
2380 PRINT"OP{cm p*16}O{cm y}P{cm p*17}OP";
2400 FORt=1TO20:PRINT"{cm h}"SPC(38)"{cm n}";:NEXT
2420 PRINT"L{cm p*38}{sh @}{home}{down*3}{right}";:RETURN
2440 GOSUB2360:PRINT"{down}{cyan}{reverse on}{space*10}computer e scuola{space*11}{reverse off}"
2445 PRINT"{right*3}{white}fiano{space*2}li{space*2}messeri{space*2}et{space*2}le{space*2}madonne{down}"
2460 PRINT"{right*5}li{space*2}benvenuti ne lo tempo dello"
2480 PRINT"{down*3}{right*10}alto{space*5}medioevo{space*2}"
2500 PRINT"{down*5}{right*2}{space*4}pigiate uno tasto par buscar"
2520 PRINT"{down}{right*2}{space*3}lo sequito di cotanta tenzone."
2540 GETa$:IFa$=""THEN2540
2560 RETURN
2580 pc=1681:FORxe=1TO6:FORex=1TO21:POKEpc+ex,32:NEXT:pc=pc+40:NEXT:RETURN
2600 k=0:FORk=0TO3:GOSUB2360:FORkk=0TO50:NEXT:PRINT"{clear}":FORkk=0TO50:NEXT:NEXT
2620 GOSUB2360:PRINT"{down}"SPC(9)"{reverse on}{cm asterisk}{sh pound}{cm asterisk}{sh pound}"SPC(11)"{cm asterisk}{sh pound}{cm asterisk}{sh pound}"SPC(11);
2640 PRINTSPC(10)"{reverse on}{space*4}"SPC(11)"{space*4}"
2660 IFll(a)=1THENPRINT"{down*8}{right*4}"n$(a)"{space*2}e' re"SPC(38)"{sh asterisk*2}"
2680 IFll(a)=6THENPRINT"{down*8}{right*4}"n$(a)"{space*2}e' regina"SPC(34)"{sh asterisk*6}"
2700 GETa$:IFa$=""THEN2700
2720 PRINT"{clear}":POKE774,26:NEW
2800 kj$(1)="{right} i langobardi di patavium clamano uno {down}{right*2}"
2810 kj$(1)=kj$(1)+" tributo {reverse on}p{reverse off}ugna o {reverse on}r{reverse off}iscatto ?"
2820 kj$(2)="{right}{space*2}il principe saracino offre li suoi{space*2}{down}{right*2}"
2830 kj$(2)=kj$(2)+"{space*2}omaggi et una regalia de scudi 500+"
2840 kj$(3)="{right} la peste accide li servi de lo regno {down}{right*2}"
2850 kj$(3)=kj$(3)+"{space*7}in numero de 40%"
2860 kj$(4)="{right} fortunata campania contra li enemici {down}{right*2}"
2870 kj$(4)=kj$(4)+"{space*5}bottino de scudi 1{0*3}+"
2880 kj$(5)="{right}{space*2}lo fiume rompe li argini tutti et{space*3}{down}{right*2}"
2890 kj$(5)=kj$(5)+" anniga li villici in numero de 10%"
2900 kj$(6)="{right}{space*2}romana cloaca a sistemarsi par lo{space*3}{down}{right*2}"
2910 kj$(6)=kj$(6)+" grande puzzo espesa de scudi 2{0*3}-"
2920 kj$(7)="{right}{space*2}banda de briganti alle porte dello{space*2}{down}{right*2}"
2930 kj$(7)=kj$(7)+" palazzo{space*2}{reverse on}p{reverse off}ugna o {reverse on}r{reverse off}iscatto ?"
2940 kj$(8)="{right}ciambellano malfido ruba li danari de {down}{right*2}"
2950 kj$(8)=kj$(8)+" lo palazzo desappaiono scudi 950-":RETURN
5000 PRINT"{clear}{space*9}della economia politica"
5010 PRINT"{down}majore est la quantitate de terreno che"
5020 PRINT"{down}lo signore possiede majore sara' lo di "
5030 PRINT"{down}lui raccolto. a cagione de questo sara'"
5040 PRINT"{down}di lui cura de aumentar lo suo possesso"
5050 PRINT"{down}a securitate per le carestie. grande{space*3}"
5060 PRINT"{down}est pure la necessitate de villici. lo "
5070 PRINT"{down}signore che sine umanitate governasse{space*2}"
5080 PRINT"{down}lo suo reame sino ad accidere le alme{space*2}"
5090 PRINT"{down}delli servi sui non avrebbe piu' a chi "
5100 PRINT"{down}prender{space*2}tributi,{space*2}e{space*2}avrebbe{space*2}a{space*2}che{space*2}"
5110 PRINT"{down}prender nuovi servi con la pugna{space*6}":GOSUB20000
5120 PRINT"{clear}facto mirabile est la pugna, et{space*2}raro"
5130 PRINT"{down}che puotesi dover attendere per anni.{space*2}"
5140 PRINT"{down}quando essa si presenti puotesi fugarla"
5150 PRINT"{down}con uno riscatto. tributi vengono dalli"
5160 PRINT"{down}nobili inferiori in rango. ogni forma{space*2}"
5170 PRINT"{down}de{space*2}possesso est{space*2}utile{space*2}nel di rango"
5180 PRINT"{down}salire. quando lo signore compra del "
5190 PRINT"{down}grano la compra non puote eccedere lo"
5200 PRINT"{down}raccolto suo. quand'egli ne vende non"
5210 PRINT"{down}lo puote ricomprare se non da lo suo{space*2}"
5220 PRINT"{down}raccolto.{space*29}":GOSUB20000
5225 PRINT"{clear}le gabelle han da esser de la justa "
5230 PRINT"{down}consistenza imperrocche' esse molto{space*2}"
5240 PRINT"{down}puoton nuocere alle casse dello{space*7}"
5250 PRINT"{down}thesauro signorile. lo signore che{space*3}"
5260 PRINT"{down}dinaro chiedesse a prestito alli{space*5}"
5270 PRINT"{down}usurai sappia che tali figuri darangli"
5280 PRINT"{down}tanto credito quanto fu lo guadagno{space*3}"
5290 PRINT"{down}dello feudo suo dell'anno che passo'. "
5300 PRINT"{down}rammenti lo signore che alla regal{space*4}"
5310 PRINT"{down}dignitate aspiri che molto fine acume "
5320 PRINT"{down}egli abbisogna.{space*23}":GOSUB20000:RETURN
20000 GETa$:IFa$=""THEN20000
20010 RETURN
30000 fl=0:in$="":ct=0
30010 GETqa$
30015 IFfl=0THENPRINT"A{left}";
30020 IFfl=1THENPRINT" {left}";
30035 kh=((qa$="{left}"ORqa$=CHR$(20))ANDin$<>"")
30040 IFkhTHENPRINT" {left*2} {left}";:in$=LEFT$(in$,LEN(in$)-1):qa$=""
30050 IFqa$=CHR$(13)THENPRINT" {left}":RETURN
30052 IFqa$=""THEN30070
30055 qw=ASC(qa$):IFNOT((qw>47ANDqw<58)OR(qw>63ANDqw<91)ORqw=32)THENqa$=""
30060 IFqa$<>""THENPRINTqa$;:in$=in$+qa$
30070 ct=ct+1:IFct=7THENfl=ABS(fl-1):ct=0:IFfl=4THENfl=0
30080 GOTO30010
52000 PRINT"{clear}{down*3}"CHR$(142)CHR$(8)
52010 PRINT"{white}{space*11}computer e scuola"
52020 PRINT"{yellow}{space*11}{cm t*17}"
52030 PRINT"{light green}{down*4}{space*7}presenta il 1{cm c} programma di"
52040 PRINT"{down*3}{right*5}{reverse on}{yellow}{space*3}simulazione del medio evo{space*3}{reverse off}"
52110 FORt=1TO3500:NEXT:RETURN
stop tok64
(bastext 1.04)
